Erlang服務器編程思想和實現

下面會寫到4個服務器程序，他們以server1，server2...這樣的方式命名，好戲即將開始深吸一口氣，go！！

更多關於Erlang的詳細信息，或者下載地址請點這裡

1.server1 原始服務器程序

server1.erl

1. -module(server1).  
2. -export([start/2, rpc/2]).  
3.   
4. start(Name, Mod) ->  
5.     register(Name, spawn(fun() -> loop(Name, Mod, Mod:init()) end)).  
6.   
7. rpc(Name, Request) ->  
8.     Name ! {self(), Request},  
9.     receive  
10.         {Name, Response} -> Response  
11.     end.  
12.   
13. loop(Name, Mod, State) ->  
14.     receive  
15.     {From, Request} ->  
16.             {Response, State1} = Mod:handle(Request, State),  
17.             From ! {Name, Response},  
18.             loop(Name, Mod, State1)  
19.     end. 

這段代碼是erlang的標准服務器程序，下面寫一個回調函數來運行測試。

name_server.erl

1. -module(name_server).  
2. -export([init/0, add/2, whereis/1, handle/2]).  
3. -import(server1, [rpc/2]).  
4.   
5. %% client routines  
6. add(Name, Place) -> rpc(name_server, {add, Name, Place}).  
7. whereis(Name)    -> rpc(name_server, {whereis, Name}).  
8.   
9. %% callback routines  
10. init() -> dict:new().  
11.   
12. handle({add, Name, Place}, Dict) -> {ok, dict:store(Name, Place, Dict)};  
13. handle({whereis, Name}, Dict)    -> {dict:find(Name, Dict), Dict}.

首先看後面的代碼1.他負責回調服務器程序，處理其他進程發貨來的請求2.相當於定義接口。

如下運行程序：

1. erlc *.erl   

1. Eshell V5.6.5  (abort with ^G)  
2. 1> server1:start(name_server, name_server).  
3. true  
4. 2> nameserver:add("lengzijian","go to school").  
5. ** exception error: undefined function nameserver:add/2  
6. 3> name_server:add("lengzijian","go to school").  
7. ok  
8. 4> name_server:whereis("lengzijian").  
9. {ok,"go to school"}  
10. 5>   

如果讀者細心可以發現，這段代碼裡面並沒有spawn這樣的創建進程的命令，不錯，這個服務器程序完全是順序性代碼，也許有人質疑這樣做的意義，不要急這才剛剛開始

2.server2：支持事務的服務器程序

接下來要向大家展示的是，當服務器宕機，客戶端回或得到異常，然後做相應的處理。

server2.erl

1. -module(server2).  
2. -export([start/2, rpc/2]).  
3.   
4. start(Name, Mod) ->  
5.     register(Name, spawn(fun() -> loop(Name,Mod,Mod:init()) end)).  
6.   
7. rpc(Name, Request) ->  
8.     Name ! {self(), Request},  
9.     receive  
10.         {Name, crash} -> exit(rpc);  
11.         {Name, ok, Response} -> Response  
12.     end.  
13.   
14. loop(Name, Mod, OldState) ->  
15.     receive  
16.     {From, Request} ->  
17.         try Mod:handle(Request, OldState) of  
18.         {Response, NewState} ->  
19.             From ! {Name, ok, Response},  
20.             loop(Name, Mod, NewState)  
21.         catch  
22.         _:Why ->  
23.             log_the_error(Name, Request, Why),  
24.             %% send a message to cause the client to crash  
25.             From ! {Name, crash},  
26.             %% loop with the *original* state  
27.             loop(Name, Mod, OldState)  
28.         end  
29.     end.  
30.   
31. log_the_error(Name, Request, Why) ->  
32.     io:format("Server ~p request ~p ~n"  
33.           "caused exception ~p~n",   
34.           [Name, Request, Why]).    

想對於之前的版本，多了注冊函數和創建進程函數，可以理解的認為是增加了並行操作，但是我之前做過一些小項目而言，erlang的進程的確有他特殊的地方，這裡會在之後的文章詳細講解，這段代碼實際上是提供了“事務機制”，在handler發生異常時，回調用loop(Name, Mod, OldState)在之前的狀態下進行循環，否則會在新的狀態下進行運行

流程是怎樣的呢：當服務端宕機，服務器會給客戶端發送crash消息，說明服務器異常，然後客戶端接收到消息後，可以做相應處理（在我們的項目中用到的是重連，例子中是退出），然後調用loop並帶入變量OldState說明本次服務處理異常，同時不影響其他連接到服務器的客戶端。

要測試的話，與server1完全相同只需要改變import時改為server2即可。